无人小站

Aria2 Tracker 更新脚本

JP-Liu Aria2BTBT Tracker

Aria2 Tracker 更新脚本

之前由于使用长城宽带,BT 需要走代理才能有一点速度,但是 Aria2 我没能找到 BT 下载走代理的方法,10月换了联通宽带,Aria2 的 BT 也能跑起来了,在4个月前的 Aria2 BT 下载的一些小细节一文中,我提到过在 Github 上有一个项目提供自动更新的Tracker列表,这里提供了一个脚本用来自动更新 Aria2 配置文件中的 TrackersList,脚本需要用到 Aria2 和 Sed。

:: Aria2 更新 Trackers
@echo off

::本 Bat 需要使用 aria2 和 sed 。
::这里使用的相对路径,有需要的可以改成绝对路径。
set aria2=aria2c.exe
::sed 需要在以下两个链接的文件,解压到同一文件夹,Bin 文件内的 sed.exe 和 dll 不能删除。
::https://sourceforge.net/projects/gnuwin32/files/sed/4.2.1/sed-4.2.1-bin.zip/download
::https://sourceforge.net/projects/gnuwin32/files/sed/4.2.1/sed-4.2.1-dep.zip/download
set sed=sed.exe

::设置当前的aria2配置文件的名称,如配置在子文件夹下,请自行修改。
set conf=aria2n.conf

::设置选择的 trackerlist (可选 trackers_all.txt trackers_best.txt trackers_all_ip.txt trackers_best_ip.txt)
set trackerfile=trackers_all.txt
set downloadfile=https://raw.githubusercontent.com/ngosang/trackerslist/master/%trackerfile%

:: 删除可能之前存在的残留文件
del %temp%\tracker*.*
del %temp%\aria*.*

::下载 trackerlist
%aria2% --dir=%temp% "%downloadfile%"

::用 sed 整理 trackerlist 格式
%sed% ":a;N;s/\n/ /; ta;" %temp%\%trackerfile% > %temp%\trackerstemp.txt
%sed% "1s/^/bt-tracker=/g; s/  /,/g; s/ $//;" %temp%\trackerstemp.txt > %temp%\trackers.txt

::删除当前 aria2 配置 中的 trackerlist
%sed% "/^bt-tracker=/d" %conf% > %temp%\aria2n.conf

::合并 trackerlist 和 aria2 配置
copy %temp%\aria2n.conf + %temp%\trackers.txt %temp%\aria2bt.txt
%sed% "$d" %temp%\aria2bt.txt > %conf%

:: 删除残留的临时文件
del %temp%\tracker*.*
del %temp%\aria*.*
exit

还是放一个下载速度的图片吧,资源好的话是可以跑满的,宿舍合租不能影响别人,我在 uGet 上限制了6MB/s。

Aria2 BT 下载速度

这个脚本在家里用了差不多有一年了,看到小众软件上提到 Github 上那个清单心血来潮的发到这里来,懒到没救了。

JP-Liu
懒人一个