WinPython 自动更新 You-Get 和 Youtube-dl

WinPython 自动更新 You-Get 和 Youtube-dl

• 2019年2月更新：调整了一下脚本，关闭脚本位置的警告。

之前在 You-Get 和 Youtube-dl 中提供过一个调用的脚本，当时 You-Get 还是提供 Windows 下的预编译版本的，但是17年10月之后，官方的 Github 上已经不再更新 Windows 下的预编译版本，但是仍在可以通过 Python 和 Pip 来使用新版。

近期找到了 WinPython, 一个可便携的 Python 环境，于是萌生了一个用 WinPython 来自动更新 You-Get 和 Youtube-dl，实现完全便携化的想法。实测确实可行，以下是操作流程。

• 下载 WinPython ，我个人选择的是 Winpython32-3.7.1.0Zero.exe。

• 双击安装，由于没有捆绑，可以一直点下一步，有需要的可以调整安装路径。

  • 虽然需要安装，但是 WinPython 安装完成后目录可以随意移动到其他位置。

• 将以下内容保存为 MediaDown.bat (名字任意，此处为示例)，放到 WinPython 安装目录下。

  @echo off
  
  
  for /d %%i in (*python-*) do set Winpython=%%~dpi%%i
  
  
  cd %Winpython%
  set youget=%Winpython%\scripts\you-get.exe
  set youtubedl=%Winpython%\scripts\youtube-dl.exe
  set pip=%Winpython%\scripts\pip.exe
  
  
  echo.&echo.通用流媒体下载工具，整合了 You-Get 与 Youtube-DL
  echo.&echo.正在尝试更新 You-Get 与 Youtube-DL
  
  
  :: 利用 pip 更新 pip、You-Get 和 Youtube-DL
  %pip% install --upgrade you-get --no-warn-script-location
  %pip% install --upgrade youtube_dl --no-warn-script-location
  
  
  set /p URL=请输入需要下载的 URL 并回车:
  
  
  :MediaDownMenu
  echo.&echo.
  echo You-Get List
  echo 11.You-Get   下载到 D:\ZeroDown ，不使用代理
  echo 12.You-Get   下载到 D:\ZeroDown ，使用代理
  echo.&echo.
  echo YoutubeDL List
  echo 21.YoutubeDL 下载到 D:\ZeroDown ，不使用代理
  echo 22.YoutubeDL 下载到 D:\ZeroDown ，使用代理
  echo.&echo.
  set /p choose=请选择相应的处理方式：
  if "%choose%"=="11" set OP=-o D:\ZeroDown &Goto YouGetDown
  if "%choose%"=="12" set OP=--http-proxy 127.0.0.1:1080 -o D:\ZeroDown\ &Goto YouGetDown
  if "%choose%"=="21" set OP=-o "D:\ZeroDown\%%(title)s.%%(ext)s" &Goto youtubedlDown
  if "%choose%"=="22" set OP=-o "D:\ZeroDown\%%(title)s.%%(ext)s" --proxy socks5://127.0.0.1:1080/ &Goto youtubedlDown
  
  
  :YouGetDown
  %youget% %OP% %URL%
  exit
  
  
  :youtubedlDown
  %youtubedl% %OP% %URL%
  exit
  

• 双击运行 MediaDown.bat，第一次运行需要使用 pip 新增 YouGet 和 Youtube-DL，耗时会比较长，之后只是检查更新会更快。

• 更新完成后，输入要下载的 URL，在选择保存的路径即可。